Hallo Mareike1985,

Dieses hier sollte die Lösung für dein Problem sein.

Gruß
gresti

Dankeschön für die schnelle Antwort.

Habe die Seite auch bereits gefunden *fg*

Das Problem ist aber, dass ich aber bereits einen Datensatz von ca. 25.000 EAN Codes habe, wovon aber nicht jeder richtig ist. Ich muss also jeden EAN überprüfen.

Daher habe ich mir folgendes System überlegt.

Die zu überprüfende EAN liegt auf A1 (zum Beispiel)
4023500041010

Mit einer leicht abgewandelten Formel spruckt er mir auch die richtige Prüfsume aus. Aber ich weiß jetzt nicht, wie ich das Ergebnis der Prüfsumme mit dem eingegebenen Datensatz vergleiche.

Feld A1 = 4023500041010
Prüfsumme A2 = 10 (korrekt)

Aber wie bekomme ich Excel nun zu folgendem:
1) vom Wert aus A1 die letzte Ziffer entfernen und auf A3 kopieren

2) die Prüfsumme aus A2 an die letzte Stelle des Wertes an A3 anfügen

3) Felder A1 und A3 vergleichen. Bei übereinstimmung soll im Feld A4 "Richtig" stehen, bei abweichungen "Falsch"

*amverzweifelnist*

3)

Hallo Mareike,

wenn in A1 eine 13-stellige Zahl steht, von der Du die Prüfziffer auf Richtigkeit prüfen willst, kannst Du das mit folgender Formel in B1 in einem Schritt erledigen.

=WENN(RECHTS(A1;1)*1=REST(10-REST(SUMMENPRODUKT((TEIL(GANZZAHL($A$1/10) ;ZEILE($1:$12);1))*{1;3;1;3;1;3;1;3;1;3;1;3});10);10);"Pz ist OK";"Richtige Pz ist: "& REST(10-REST(SUMMENPRODUKT((TEIL(GANZZAHL($A$1/10);ZEILE($1:$12);1))*{1;3;1;3;1;3;1;3;1;3;1;3});10);10))

Formel ohne Leerzeichen und Zeilenumbrüche eingeben!!!

Mit folgender Formel in C1 wird dann die korrigierte 13-stellige erzeugt.

=(LINKS(A1;12)*1&REST(10-REST(SUMMENPRODUKT((TEIL(GANZZAHL($A$1/10);ZEILE($1:$12);1))*{1;3;1;3;1;3;1;3;1;3;1;3});10);10))*1

Gruß
Rainer

DANKE!!!!

Die Formel ist Gold Wert. Solltest das beruflich machen *zwinker*

Funktioniert alles, wie es soll...aber Excel jault etwas mit "Zirkelbezug" herum. Sagt dir das etwas?

Sorry...bin in Excel noch ein blutiger Anfänger *sichschämt*

Hallo Mareike,

im Normalfall kann bei beiden Formeln kann kein Zirkelbezug entstehen, wenn Du sie so eingertragen hast, wie beschrieben.
Es sei denn Du willst sie nach rechts kopieren, dann müssten die Bezüge auf A1 angepasst werden.

Alle $A$1 und A1 in den Formeln müssen in diesem Falle in
$A1
geändert werden

Gruß
Rainer

Hallo!
Ich hoffe, dass ich jetzt niemanden auf den Schlips trete, wenn ich (ausgerechnet als neu angemeldetes Mitglied) einen alten Beitrag rauskrame.

Rainer (Rainberg) hat ja oben die lange Formel gepostet, die in Excel eine vorhandene 13-stellige EAN-Nummer bezüglich der Prüfziffer testen soll.

Leider klappt es bei mir nicht tadellos. Viele (genauer gesagt ca. 19.000 von ca. 21.000) EANs werden als falsch angezeigt, obwohl Stichproben ergeben haben, dass diese richtig sind.

Beispiel:

4008874821765 Pz ist OK
5000621222220 Richtige Pz ist: 5
5000621100009 Richtige Pz ist: 5
4007535481935 Pz ist OK

Kopiere ich die EAN aus Zeile 2 in Zeile 1, wird diese plötzlich als korrekt erkannt. Woran liegt das? Vielleicht ein Bug in Excel 2007 SP1 oder mache ich etwas falsch?

Ich exportiere die Daten direkt aus dem WWS in eine Excel Datei, öffne die Datei mit Excel 2007 SP1 und füge in Spalte B die genannte Formel und lasse nach unten auffüllen. Habe nun in Spalte C die Formel zur Errechnung einer korrekten EAN eingegeben, da kommt dann auch das falsche Ergebnis raus.

Weiß echt nicht weiter, aber sicher hat hier jemand eine Idee.

Viele Grüße
Thomas

Hallo Thomas,

ich mag Schlipsträger nicht besonders, deshalb trage ich keinen :-)

Auf alle Fälle ist Deine Nachfrage berechtigt und keinesfalls beleidigend.

Meine Antwort:
Obige Formeln sind dafür konzipiert, dass der 13-stellige EAN-Code ausschließlich in A1 steht.
Deshalb habe ich in beiden Formeln den absoluten Bezug $A$1 gewählt.

Wenn Du die Formeln nach unten kopieren und immer auf die aktuelle Zeile anwenden willst, musst Du den Zeilenbezug in relativ ändern.

D. h. konkret:

Ändere in beiden Formeln alle Bezüge $A$1 in $A1

Damit sollte alles geklärt sein.

Gruß
Rainer