B1:

=MAX(A1:A10)

B2:

=MIN(A1:A10)

ich muss meine Frage erweitern.

in Zelle A1 bis A10 steht jeweils ein Datum (15.01.07, 29.03.07, 26.06.07, ..........................)
in Zelle B1 bis B10 stehen errechnete Werte

in Zelle C1 soll der Höchstwert aus Zelle B1 bis B10 stehen. Jedoch darf die Formel nur auf die Werte zugreifen die mit dem Datum 01.01.07 bis 31.03.07 verbunden sind.
So soll es dann weiter gehen für das Datum des zweiten Quartals, usw.

Das gleiche Prozedere min Kleinstwert und das gleiche Vorgehen mit Durchschnittswert

Das einfachste wäre die Werte pro Quartal in separate Tabellen zu packen oder wenigstens mittels WENN-Formel nach Zeitraum getrennt in andere Spalten zu übernehmen.
Wenn die Werte nach Zeitraum in getrennten Spalten stehen, dann lässt sich auf diese Spalten Problemlos MIN() ,MAX() und MITTELWERT() weiter anwenden.

Hallo Joker 61,

schreibe in C1 folgende Formel, schließe die Eingabe mit der Tastenkombination Strg+Shift+Enter ab und kopiere die Formel bis in Zeile 4.

=MIN(WENN(AUFRUNDEN(MONAT(A$1:A$10)/3;0)=ZEILE(1:1);B$1:B$10))

Damit erhältst Du von oben nach unten die MIN-Werte des 1. bis 4. Quartals.

Die gleiche Prozedur wiederholst Du mit folgender Formel in Spalte D, um die MAX-Werte der Quartale zu erhalten.

=MAX(WENN(AUFRUNDEN(MONAT(A$1:A$10)/3;0)=ZEILE(1:1);B$1:B$10))

Gruß
Rainer

Hallo Joker61,

hatte den Mittelwert vergessen. Wieder gleiche Prozedur mit folgender Formel

=MITTELWERT(WENN(AUFRUNDEN(MONAT(A$1:A$10)/3;0)=ZEILE(1:1);B$1:B$10))

Gruß
Rainer

also irgendwie kriege ich es nicht hin.

@ChatAlligator: kannst du mir mal deine Version etwas näher bringen. Vielleicht mit einer Beispielformel.

@Rainer: vielleicht funktioniert es bei mir nicht weil ich etwas übersehen habe.

Das Datum und die Werte sind folgendermaßen aufgebaut:

F6 Datum BS6 Wert
F7 leer BS7 leer
F8 leer BS8 leer
F9 Datum BS9 Wert
F10 leer BS10 leer
F11leer BS10 leer
F12 Datum BS11 Wert

usw.

Ich beschränke mich mal der Einfachheit halber auf ein Beispiel gemäß Antwort2

D1:

=WENN(UND(A1>=DATWERT("01.01.07");A1<DATWERT("01.04.07"));B1;"")

E1:

=WENN(UND(A1>=DATWERT("01.04.07");A1<DATWERT("01.07.07"));B1;"")

F1:

=WENN(UND(A1>=DATWERT("01.06.07");A1<DATWERT("01.09.07"));B1;"")

G1:

=WENN(UND(A1>=DATWERT("01.09.07");A1<DATWERT("01.01.08"));B1;"")

Wenn diese 4 Zellen so oft unter einander kopiert werden, wie verwendete Zeilen der ursprünglichen Daten vorhanden sind, dann stehen in Spalte D alle Werte aus Quartal1, in Spalte E alle aus Quartal2, in Spalte F alle aus Quartal3, in Spalte G alle aus Quartal4.
MIN(), MAX() und MITTELWERT() können dann einfach auf die unterschiedlichen Spalten angewendet werden, die je immer nur ein Quartal darstellen

Hallo joker,

wenn sich zwischen Deinen Daten immer zwei leere Zellen befinden, gilt für das Minimum des 1. Quartals folgende Matrixformel.
Formel funktioniert für den Zeilenbereich 6-1000, kannst Du beliebig anpassen. Wähle den Bereich immer so klein wie möglich.

=MIN(WENN((AUFRUNDEN(MONAT(F$6:F$1000)/3;0)=ZEILE(1:1))*(BS$6:BS$1000<>"");BS$6:BS$1000))

für das Maximum und den Mittelwert gilt die gleiche Formel, brauchst nur den Funktionsnamen auszutauschen.
Für die Folgequartale die Formeln einfach runterkopieren.

Falls die Zwischenzellen nicht leer sind musst Du noch mal mitteilen, was genau drin steht.

Gruß
Rainer